aprenda aaa
;Escreva a palavra janela na janela de comandos
;e aperte enter.
fim

aprenda ajuste
atribua "q barrarolagem "r1
atribua "n barrarolagem "r2
senão :q >6 [atribua "l 40] [ atribua "l 120]
senão caixamarcação "m1 [at][dt]
senão caixamarcação "m2 [ fractal1 :l :q :n] [fractal :l :q :n]
fim

aprenda frac :l :q :n
se :n=0[pf :l pare]
frac :l/3 :q :n-1
pe 180-(360/:q)
repita :q-1[frac :l/3 :q :n-1 pd (360/:q)]
pe 180
frac :l/3 :q :n-1 
fim

aprenda fractais
apaguejanela "fra1
criejanela "main "fra [FRACTALIZANDO POLíGONOS] 0 0  240 200
crieestático "fra "e1 [Modo de execução] 5 45 80 10
criecaixagrupo "fra "g1 5 12 70 27
criecaixamarcação "fra "g1 "m1 [exibir tartaruga] 7 17 60 10
criecaixamarcação "fra "g1 "m2 [esconder janela] 7 27 65 10
crieestático "fra "e2 [Número de lados] 85 5 80 10
criebarrarolagem "fra "r1 85 15 70 10 [lado]
mudebarrarolagem "r1 3 8 3 lado
crieestático "fra "e3 [Nível do fractal] 85 25 70 10 
criebarrarolagem "fra "r2 85 35 70 10 [nível]
mudebarrarolagem "r2 0 3 0 nível
criebotão "fra "b1 "DESENHA 5 50 40 10 [ajuste]
criebotão "fra "b2 "LIMPA 60 50 40 10 [tat]
criebotão "fra "b3 "SAI 115 50 40 10 [apaguejanela "fra]
fim

aprenda fractal :l :q :n
mudecl (lista sortnum 255 sortnum 255 sortnum 255)
repita :q[frac :l :q :n pd 360/:q]
fim

aprenda fractal1 :l :q :n
apaguejanela "fra 
fractal :l :q :n
fractais
fim

aprenda janela
criejanela "main "fra1 [FRACTALIZANDO POLÍGONOS] 20 10 240 180
crieestático "fra1 "est1 [UNIVERSIDADE DO RIO GRANDE DO SUL] 55 15 190 10
crieestático "fra1 "est2 [ INSTITUTO DE MATEMÁTICA] 75 25 100 20
crieestático "fra1 "est3 [CARLOS ALEXANDRE SELBACH] 35 45 120 20
crieestático "fra1 "est4 [KATILENE GRILO CONTE] 35 65 200 20
crieestático "fra1 "est5 [ PROFESSORA :  MARIA ALICE GRAVINA] 35 85 200 20 
crieestático "fra1 "est6 [ PORTO ALEGRE, DEZEMBRO DE 1997.] 35 105 200 20
crieestático "fra1 "est7 [ Adaptação para SLogo 3.0 por Alexandre R Soares.] 35 115 200 20
criebotão "fra1 "b1 "CONTINUAR 65 145 60 10 [FRACTAIS]
criebotão "fra1 "b2 "SAIR 155 145 40 10 [apaguejanela "fra1]
fim

aprenda lado
mudeestático "e2 sentença [Número de lados] barrarolagem "r1
fim

aprenda mudecl :cor
atr "valido 0
se élista pri :cor [mudecll (pri :cor) atr "valido 1 atr "cor 16]
se élista :cor [mudecll (:cor) atr "valido 1]
se ou :cor = 0  :cor = "preto          [ mudecll ( lista 0 0 0 )]
se ou :cor = 1  :cor = "azul           [ mudecll ( lista 0 0 128 )]
se ou :cor = 2  :cor = "verde          [ mudecll ( lista 0 128 0 )]
se ou :cor = 3  :cor = "ciano          [ mudecll ( lista 0 128 128 )]
se ou :cor = 4  :cor = "vermelho       [ mudecll ( lista 255 0 0 )]
se ou :cor = 5  :cor = "roxo           [ mudecll ( lista 128 0 128 )]
se ou :cor = 6  :cor = "marom         [ mudecll ( lista 128 64 0 )]
se ou :cor = 7  :cor = "cinzaclaro     [ mudecll ( lista 192 192 192 )]
se ou :cor = 8  :cor = "cinzaescuro    [ mudecll ( lista 128 128 128 )]
se ou :cor = 9  :cor = "verdeágua      [ mudecll ( lista 128 255 255 )]
se ou :cor = 10 :cor = "verdeclaro     [ mudecll ( lista 0 255 0 )]
se ou :cor = 11 :cor = "cianoclaro     [ mudecll ( lista 0 255 255 )]
se ou :cor = 12 :cor = "vermelhoescuro [ mudecll ( lista 128 0 0  )]
se ou :cor = 13 :cor = "rosachoque     [ mudecll ( lista 255 0 255 )]
se ou :cor = 14 :cor = "amarelo        [ mudecll ( lista 255 255 0 )]
se ou :cor = 15 :cor = "branco         [ mudecll ( lista 255 255 255 )]
se :valido = 0 [esc [Está cor não é válida!]]
fim

aprenda nível 
mudeestático "e3 sentença [Nível do fractal] barrarolagem "r2
fim